/*
===========================================================
	IMP-PROJECT: ESCAPE-IRTC ENTRY                            
===========================================================
http://www.imp.org                                         


-----------------------------------------------------------
GENERAL
-----------------------------------------------------------
Scale: 		1cm = 1 POV-Unit    
         

-----------------------------------------------------------
THIS FILE
-----------------------------------------------------------
This file is the main scene file. All the objects from the
include files are used and positioned here.  
If you want to render the scene, use this file.

Version:	0.02
Created by:	Florian Brucker (torf (at) torfbold.com) 
Edited by:	Andy Read (Andy (at) Azurite.co.uk) 
*/

/*
camera {
	location <-200,180,0>
	look_at y*150        
	rotate y*360*0.6
}         
*/

//SOME DECLARES
#declare ROOMS_DOOR_WIDTH = 95;
#declare ROOMS_DOOR_HEIGHT = 200;
#declare ROOMS_WALL_THICKNESS = 10;

#declare ROOM1_WIDTH = 500;
#declare ROOM1_DEPTH = 500;
#declare ROOM1_HEIGHT = 220;              
#declare ROOM1_WINDOW_WIDTH = 130;
#declare ROOM1_WINDOW_HEIGHT = 120;


camera {
	//location <25,15,-35>
	location <20,110,ROOM1_DEPTH/2-40>
	look_at <0,15,0>
}          


//INCLUDES FOR ALL ROOMS
#include "rooms_door.inc"

//INCLUDES FOR ROOM1    
#include "room1_textures.inc"
#include "room1_floor.inc"      
#include "room1_ceiling.inc"    
#include "room1_window.inc"
#include "furniture_bed.inc" 
#include "furniture_bedsidetable.inc"        
#include "furniture_desk.inc"   
#include "furniture_desk_chair.inc" 
#include "furniture_plant.inc"
#include "furniture_shelves.inc"
#include "furniture_cupboard.inc"
#include "furniture_shelves2.inc"    
#include "furniture_picture.inc"
#include "furniture_picture2.inc"      
#include "furniture_lamp.inc"     
#include "furniture_cupboard2.inc"
#include "cards.inc"

sky_sphere {
	pigment {
		bozo
		color_map {
			[ 0.3 rgb 1 ]
			[ 0.5 rgb <0.5,0.5,1> ]
		}
		scale 1/10
	}
}

global_settings {
	assumed_gamma 1
}

//=========================================================
//	ROOM 1
//=========================================================

union {
	difference {              
		box { 
			<-(ROOM1_WIDTH/2 + ROOMS_WALL_THICKNESS),-ROOMS_WALL_THICKNESS,-(ROOM1_DEPTH/2 + ROOMS_WALL_THICKNESS)>,
			<(ROOM1_WIDTH/2 + ROOMS_WALL_THICKNESS),ROOM1_HEIGHT + ROOMS_WALL_THICKNESS,(ROOM1_DEPTH/2 + ROOMS_WALL_THICKNESS)>
		}
		box { 
			<-ROOM1_WIDTH/2,-1,-ROOM1_DEPTH/2>,
			<ROOM1_WIDTH/2,ROOM1_HEIGHT + 1,ROOM1_DEPTH/2>
			texture { ROOM1_TEX_WALLS }
		}      
		                                
		//WINDOWS		
		object { ROOM1_WINDOW_CUTTER translate <-1/5*ROOM1_WIDTH,80,ROOM1_DEPTH/2> }
		object { ROOM1_WINDOW_CUTTER translate <1/5*ROOM1_WIDTH,80,ROOM1_DEPTH/2> }		
		
		
		//DOOR
		object { 
			ROOMS_DOOR_CUTTER
			rotate y*90
			translate <-1/2*ROOM1_WIDTH,0,-1/3*ROOM1_DEPTH>
		}
	}  
		
	//FLOOR    
	object { ROOM1_FLOOR }
	
	//CEILING
	object { ROOM1_CEILING translate y*ROOM1_HEIGHT }
	
	//WINDOWS                                                                   
	object { ROOM1_WINDOW translate <-1/5*ROOM1_WIDTH,80,ROOM1_DEPTH/2> }
	object { ROOM1_WINDOW translate <1/5*ROOM1_WIDTH,80,ROOM1_DEPTH/2> }
	
	//DOOR
	object { 
		ROOMS_DOOR(-0.3)
		rotate y*90
		translate <-1/2*ROOM1_WIDTH,0,-1/3*ROOM1_DEPTH>
	}
	
	
	//OTHER FURNITURE
	object { FURNITURE_BED translate <-(ROOM1_WIDTH/2-5),0,ROOM1_DEPTH/2-5> }
	object { FURNITURE_BEDSIDETABLE translate <-(ROOM1_WIDTH/2-5),0,110> }
	object { FURNITURE_DESK translate <-20,0,(ROOM1_DEPTH/2-5)> }
	object { FURNITURE_DESK_CHAIR translate z*150 }
	object { FURNITURE_PLANT translate <ROOM1_WIDTH/2-40,0,ROOM1_DEPTH/2-40> }
	object { FURNITURE_SHELVES rotate y*90 translate <ROOM1_WIDTH/2-5,0,50> }
	object { FURNITURE_CUPBOARD rotate y*90 translate <ROOM1_WIDTH/2-1,0,-150> }
	object { FURNITURE_SHELVES2 rotate y*180 translate <-100,110,-(ROOM1_DEPTH/2)> }   
	object { FURNITURE_PICTURE rotate y*180 translate <60,130,-ROOM1_DEPTH/2> }
	object { FURNITURE_PICTURE2 rotate y*180 translate <100,60,-ROOM1_DEPTH/2> }
	object { FURNITURE_LAMP translate y*ROOM1_HEIGHT }           
	object { FURNITURE_CUPBOARD2 rotate y*-90 translate <-(ROOM1_WIDTH/2-5),0,-20> }
				
        //A STATIC HOUSE OF CARDS
        object { HouseOfCards(4) rotate y*90 translate <2,74,ROOM1_DEPTH/2-90> }
        //object { CardPackDrop(75) translate <0,0,0> }
	
	pigment { rgb <1,0,0> }
	
}